Search across multiple lines

Vim can search for text that spans multiple lines. For example, the search /hello\_sworld finds "hello world" in a single line, and also finds "hello" ending one line, with "world" starting the next line. In a search, \s finds space or tab, while \_s finds newline or space or tab: an underscore adds a newline to any character class.

This tip shows how to search over multiple lines, and presents a useful command so entering :S hello world finds "hello" followed by "world" separated by spaces or tabs or newlines, and :S! hello world allows any non-word characters, including newlines, between the words.

Patterns including end-of-lineEdit

The search /^abc finds abc at the beginning of a line, and /abc$ finds abc at the end of a line. However, in /abc^def and /abc$def the ^ and $ are just ordinary characters with no special meaning. By contrast, each of the following has a special meaning anywhere in a search pattern.

Example searches:

/abc\n*def

Finds abc followed by zero or more newlines then def.

Finds abcdef or abc followed by blank lines and def.

The blank lines have to be empty (no space or tab characters).

/abc\_s*def

Finds abc followed by any whitespace or newlines then def.

Finds abcdef or abc followed by blank lines and def.

The blank lines can contain any number of space or tab characters.

There may be whitespace after abc or before def.

/abc\_$\_s*def

Finds abc at end-of-line followed by any whitespace or newlines then def.

There must be no characters (other than a newline) following abc.

There can be any number of space, tab or newline characters before def.

/abc\_s*\_^def

Finds abc followed by any whitespace or newlines then def where def begins a line.

There must be no characters (other than a newline) before def.

There can be any number of space, tab or newline characters after abc.

/abc\_$def

Finds nothing because \_$ is "zero width" so the search is looking for abcdef where abc is also at end-of-line (which cannot occur).

/abc\_^def

Finds nothing because \_^ is "zero width" so the search is looking for abcdef where def is also at beginning-of-line (which cannot occur).

/abc\_.\{-}def

Finds abc followed by any characters or newlines (as few as possible) then def.

Finds abcdef or abc followed by any characters then def.

Searching for multiline HTML commentsEdit

It is common for comments in HTML documents to span several lines:

<!-- This comment
 covers two lines. -->

The following search finds any HTML comment:

/<!--\_.\{-}-->

The atom \_. finds any character including end-of-line. The multi \{-} matches as few as possible (stopping at the first "-->"; the multi * is too greedy and would stop at the last occurrence).

Syntax highlighting may be not be accurate, particularly with long comments. The following command will improve the accuracy when jumping in the file, but may be slower (:help :syn-sync):

:syntax sync fromstart

Searching over multiple linesEdit

A pattern can find any specified characters, for example, [aeiou] matches 'a' or 'e' or 'i' or 'o' or 'u'. In addition, Vim defines several character classes. For example, \a is [A-Za-z] (matches any alphabetic character), and \A is [^A-Za-z] (opposite of \a; matches any non-alphabetic character). :help /\a

An underscore can be used to extend a character class to include a newline (end of line). For example, searching for \_[aeiou] finds a newline or a vowel, so \_[aeiou]\+ matches any sequence of vowels, even a sequence spanning multiple lines. Similarly, \_a\+ matches any sequence of alphabetic characters, even when spanning multiple lines.

The following search pattern finds "hello world" where any non-alphabetic characters separate the words:

hello\_[^a-zA-Z]*world

The above pattern (which is equivalent to hello\_A*world) matches "helloworld", and "hello? ... world", and similar strings, even if "hello" is on one line and "world" is on a following line.

Searching over multiple lines with a user commandEdit

The script below defines the command :S that will search for a phrase, even when the words are on different lines. Examples:

:S hello world

Searches for "hello" followed by "world", separated by whitespace including newlines.

:S! hello world

Searches for "hello" followed by "world", separated by any non-word characters (whitespace, newlines, punctuation).

Finds, for example, "hello, world" and "hello+world" and "hello ... world". The words can be on different lines.

After entering the command, press n or N to search for the next or previous occurrence.

Put the following in your vimrc (or in file searchmultiline.vim in your plugin directory):

" Search for the ... arguments separated with whitespace (if no '!'),
" or with non-word characters (if '!' added to command).
function! SearchMultiLine(bang, ...)
  if a:0 > 0
    let sep = (a:bang) ? '\_W\+' : '\_s\+'
    let @/ = join(a:000, sep)
  endif
endfunction
command! -bang -nargs=* -complete=tag S call SearchMultiLine(<bang>0, <f-args>)|normal! /<C-R>/<CR>

See alsoEdit

• Searching how to search
• Search patterns regex information and examples
• Search for visually selected text search for selected text; finds targets on multiple lines

ReferencesEdit

• :help pattern

CommentsEdit

Read more

• “

  This tip shows how to search using Vim, including use of * (the super star) to search for the...

  Searching
• “

  When doing a complex substitution with a regular expression, it's useful to first search for...

  Substitute last search
• “

  Several methods allow you to copy all search matches (search hits). Usually, you want to copy...

  Copy search matches

• VimTip
• Searching